'From etoys2.1 of 26 July 2007 [latest update: #1556] on 16 August 2007 at 10:34:14 pm'!
"Change Set:		noEmptyMenus-sw
Date:			16 August 2007
Author:			Scott Wallace

TRAC 2808:  Don't show a menu icon in a viewer for a slot/variable which would have no menu items to offer in such a menu."!


!CategoryViewer methodsFor: 'entries' stamp: 'sw 8/16/2007 22:23'!
phraseForVariableFrom: aMethodInterface
	"Return a structure consisting of tiles and controls and a readout representing a 'variable' belonging to the player, complete with an appropriate readout when indicated.  Functions in both universalTiles mode and classic mode.  Slightly misnamed in that this path is used for any methodInterface that indicates an interesting resultType."

	| anArrow slotName getterButton cover inner aRow doc setter tryer universal hotTileForSelf spacer |
	aRow _ ViewerLine newRow
		color: self color;
		beSticky;
		elementSymbol: (slotName _ aMethodInterface selector);
		wrapCentering: #center;
		cellPositioning: #leftCenter.
	universal _ scriptedPlayer isUniversalTiles.

	(self wantsInfoButtonFor: slotName)
		ifFalse:
			[aRow addMorphBack: IconicButton spacer]
		ifTrue:
			[aRow addMorphBack: (self infoButtonFor: slotName)].

	aRow addMorphBack: (Morph new extent: 2@0; beTransparent).

	universal
		ifTrue:
			[inner _ scriptedPlayer universalTilesForGetterOf: aMethodInterface.
			cover _ Morph new color: Color transparent.
			cover extent: inner fullBounds extent.
			(getterButton _ cover copy) addMorph: cover; addMorphBack: inner.
			cover on: #mouseDown send: #makeUniversalTilesGetter:event:from: 
					to: self withValue: aMethodInterface.
			aRow addMorphFront:  (tryer _ ScriptingSystem tryButtonFor: inner).
			tryer color: tryer color lighter lighter]
		ifFalse:
			[hotTileForSelf _ self tileForSelf bePossessive.
			hotTileForSelf  on: #mouseDown send: #makeGetter:event:from:
				to: self
				withValue: (Array with: aMethodInterface selector with: aMethodInterface resultType).
			aRow addMorphBack: hotTileForSelf.
			aRow addMorphBack: (spacer _ Morph new color: self color; extent: 0@0).
			spacer on: #mouseEnter send: #addGetterFeedback to: aRow.
			spacer on: #mouseLeave send: #removeHighlightFeedback to: aRow.
			spacer on: #mouseLeaveDragging send: #removeHighlightFeedback to: aRow.
			spacer  on: #mouseDown send: #makeGetter:event:from:
				to: self
				withValue: (Array with: aMethodInterface selector with: aMethodInterface resultType).
			hotTileForSelf on: #mouseEnter send: #addGetterFeedback to: aRow.
			hotTileForSelf on: #mouseLeave send: #removeHighlightFeedback to: aRow.
			hotTileForSelf on: #mouseLeaveDragging send: #removeHighlightFeedback to: aRow.
			getterButton _ self getterButtonFor: aMethodInterface selector type: aMethodInterface resultType].
	aRow addMorphBack: getterButton.
	getterButton on: #mouseEnter send: #addGetterFeedback to: aRow.
	getterButton on: #mouseLeave send: #removeHighlightFeedback to: aRow.
	getterButton on: #mouseLeaveDragging send: #removeHighlightFeedback to: aRow.
	(doc _ aMethodInterface documentation) ifNotNil:
		[getterButton setBalloonText: doc].

	universal ifFalse:
		[(slotName == #seesColor:) ifTrue:
			[self addIsOverColorDetailTo: aRow.
			^ aRow].
		(slotName == #color:sees:) ifTrue:
			[self addColorSeesDetailTo: aRow.
			^ aRow].
		(#(touchesA: overlaps: overlapsAny:) includes: slotName) ifTrue:
			[self addPlayerArgumentTo: aRow.
			^ aRow]].

	aRow addMorphBack: (AlignmentMorph new beTransparent).  "flexible spacer"
	(setter _ aMethodInterface companionSetterSelector) ifNotNil:
		[aRow addMorphBack: (Morph new color: self color; extent: 2@10).  " spacer"
		anArrow _ universal 
			ifTrue: [self arrowSetterButton: #newMakeSetterFromInterface:evt:from:  
						args: aMethodInterface]
			ifFalse: [self arrowSetterButton: #makeSetter:from:forPart:
						args: (Array with: slotName with: aMethodInterface resultType)].
		anArrow beTransparent.
		universal ifFalse:
			[anArrow on: #mouseEnter send: #addSetterFeedback to: aRow.
			anArrow on: #mouseLeave send: #removeHighlightFeedback to: aRow.
			anArrow on: #mouseLeaveDragging send: #removeHighlightFeedback to: aRow].
		aRow addMorphBack: anArrow].
	(#(color:sees: playerSeeingColor copy touchesA: overlaps: getTurtleAt: getTurtleOf:) includes: slotName) ifFalse:
 		[(universal and: [slotName == #seesColor:]) ifFalse:
			[aMethodInterface wantsReadoutInViewer ifTrue: 
				[aRow addMorphBack: (self readoutFor: slotName type: aMethodInterface resultType readOnly: setter isNil getSelector: aMethodInterface selector putSelector: setter)]]].
	anArrow ifNotNil: [anArrow step].
	^ aRow! !

!CategoryViewer methodsFor: 'entries' stamp: 'sw 8/16/2007 22:27'!
wantsInfoButtonFor: slotName
	"Answer whether a menu button is desired in a viewer for a slot of the given name."

	^ (#(color:sees: seesColor: overlaps: overlapsAny: touchesA:) includes: slotName) not! !