'From etoys2.1 of 26 July 2007 [latest update: #1600] on 7 September 2007 at 4:14:01 pm'!
"Change Set:		trimReleaseBuilder-tak
Date:			7 September 2007
Author:			Takashi Yamamiya

Remove some projects in the image, and trim verbose messages.
- Remove DemonCastle.pr and Welcome.pr in the release image.
- Remove too much inform in release process to keep it simple, stupid."!


!ReleaseBuilder methodsFor: 'utilities' stamp: 'tak 9/7/2007 16:01'!
cleanUpEtoys
	"ReleaseBuilder new cleanUpEtoys"


	StandardScriptingSystem removeUnreferencedPlayers.
	Project removeAllButCurrent.

	#('Morphic-UserObjects' 'EToy-UserObjects' 'Morphic-Imported' )
		do: [:each | SystemOrganization removeSystemCategory: each]! !


!ReleaseBuilderSqueakland methodsFor: 'olpc' stamp: 'tak 9/7/2007 15:32'!
buildInitialScreenForOLPC
	"ReleaseBuilderSqueakland new buildInitialScreenForOLPC2"

	World
		submorphsDo: [:m | m delete].
	Flaps disableGlobalFlaps: false.
	Flaps enableEToyFlaps.

	ProjectLoading loadFromImagePath: 'Gallery'.
	ProjectLoading openFromImagePath: 'Launcher'.
! !

!ReleaseBuilderSqueakland methodsFor: 'olpc' stamp: 'tak 9/7/2007 15:57'!
cleanupForOLPC
	"Perform various image cleanups in preparation for making a Squeak gamma release candidate image."
	"ReleaseBuilderSqueakland new cleanupForOLPC"
	
	self
		initialCleanup;
		finalStripping;
		installReleaseSpecificsForOLPC;
		finalCleanup.
	Preferences cambridge.
	Display isVirtualScreen ifTrue: [
		OLPCVirtualScreen unInstall
	].
	Display newDepth: 16.
	Project current displayDepth: 16.
	PartsBin  rebuildIconsWithProgress.
! !

!ReleaseBuilderSqueakland methodsFor: 'olpc' stamp: 'tak 9/7/2007 15:34'!
testPrerequired
	| directory entries projectNames |
	projectNames := #('Gallery' 'Launcher' ).
	directory := FileDirectory on: Smalltalk imagePath.
	entries := FileList2 projectOnlySelectionMethod: directory entries.
	projectNames
		do: [:projectName | (entries
					anySatisfy: [:each | (Project parseProjectFileName: each first) first = projectName])
				ifFalse: [^ self error: projectName , ' is not found']].
	"Test if the screen resolution is correct"
	Display extent = (1200 @ 900)
		ifFalse: [^ self error: 'The display extent should be 1200 @ 900'].
! !


!SystemDictionary methodsFor: 'shrinking' stamp: 'tak 9/7/2007 15:58'!
abandonTempNames
	"Replaces every method by a copy with no source pointer or
	encoded temp names."
	"Smalltalk abandonTempNames"
	| oldMethods newMethods n m |
	self forgetDoIts; garbageCollect.
	oldMethods := OrderedCollection new.
	newMethods := OrderedCollection new.
	n := 0.
	'Removing temp names to save space...'
		displayProgressAt: Sensor cursorPoint
		from: 0
		to: CompiledMethod instanceCount
		during: [:bar | self systemNavigation
				allBehaviorsDo: [:cl | cl selectors
						do: [:sel | 
							bar value: (n := n + 1).
							m := cl compiledMethodAt: sel.
							oldMethods addLast: m.
							newMethods
								addLast: (m copyWithTrailerBytes: #(0 ))]]].
	oldMethods asArray elementsExchangeIdentityWith: newMethods asArray.
	SmalltalkImage current closeSourceFiles.
	self flag: #shouldUseAEnsureBlockToBeSureThatTheFileIsClosed.
	"sd: 17 April 2003"
	Preferences disable: #warnIfNoChangesFile.
	Preferences disable: #warnIfNoSourcesFile! !