'From etoys2.2 of 24 September 2007 [latest update: #1697] on 10 October 2007 at 8:13 pm'!
"Change Set:		worldRecolorHalo-sw
Date:			10 October 2007
Author:			Scott Wallace

Make the recolor handle available in the world halo.
Make the extended property-sheet for the world *not* offer irrelevant and dangerous border-width and drop-shadow items."!


!ObjectPropertiesMorph methodsFor: '*connectors-visual properties' stamp: 'sw 10/10/2007 18:34'!
rebuild
	"Rebuild the contents of the property sheet."

	| buttons |
	self removeAllMorphs.
	self addARow: {
		self lockedString: ('Properties for {1}' translated format: {myTarget topRendererOrSelf externalName}).
	}.
"	self addARow: {
		self inAColumn: {
			self paneForCornerRoundingToggle.
			self paneForStickinessToggle.
			self paneForLockedToggle.
		}.
	}."

	self addARow: {
		self paneForMainColorPicker.
		self paneFor2ndGradientColorPicker.
	}.

	(myTarget isMorph and: [myTarget isWorldMorph]) ifFalse:
		[self addARow: {
			self paneForBorderColorPicker.
			self paneForShadowColorPicker}].

	buttons _ OrderedCollection new.
	buttons addAll: {
	self 
			buttonNamed: 'Accept' translated action: #doAccept color: color lighter 
			help: 'keep changes made and close panel' translated.
		self 
			buttonNamed: 'Cancel' translated action: #doCancel color: color lighter 
			help: 'cancel changes made and close panel' translated.
	}.
	
	self addOptionalButtonsTo: buttons.
	self addARow: buttons.

	thingsToRevert _ Dictionary new.
	thingsToRevert at: #fillStyle: put: myTarget fillStyle.
	myTarget isSystemWindow ifTrue: [
		thingsToRevert at: #setWindowColor: put: myTarget paneColorToUse
	].
	thingsToRevert at: #hasDropShadow: put: myTarget hasDropShadow.
	thingsToRevert at: #shadowColor: put: myTarget shadowColor.
	(myTarget respondsTo: #borderColor:) ifTrue: [
		thingsToRevert at: #borderColor: put: myTarget borderColor.
	].

	thingsToRevert at: #borderWidth: put: myTarget borderWidth.
	thingsToRevert at: #cornerStyle: put: myTarget cornerStyle.
	thingsToRevert at: #sticky: put: myTarget isSticky.
	thingsToRevert at: #lock: put: myTarget isLocked.
! !


!Preferences class methodsFor: 'halos' stamp: 'sw 10/10/2007 18:30'!
haloSpecificationsForWorld
	| desired |
	"Answer a list of HaloSpecs that describe which halos are to be used on a world halo, what they should look like, and where they should be situated"
	"Preferences resetHaloSpecifications"

	desired _ #(addDebugHandle: addMenuHandle: addTileHandle: addViewHandle: addHelpHandle: addScriptHandle: addPaintBgdHandle: addRecolorHandle:).
	^ self haloSpecifications select:
		[:spec | desired includes: spec addHandleSelector]! !