'From etoys2.2 of 27 September 2007 [latest update: #1715] on 19 October 2007 at 10:00:46 pm'!
"Change Set:		cleanupMOSupport2-tak
Date:			19 October 2007
Author:			Takashi Yamamiya

- Rename NaturalLanguageTranslator2 to NaturalLanguageTranslator.
- InternalTranslator becames a subclass of NaturalLanguageTranslator.
- Cleanup startup process of NaturalLanguageTranslator.
"!

TestCase subclass: #GetTextTranslatorTest
	instanceVariableNames: ''
	classVariableNames: ''
	poolDictionaries: ''
	category: 'System-Localization'!
TestCase subclass: #GettextTest
	instanceVariableNames: ''
	classVariableNames: ''
	poolDictionaries: ''
	category: 'Multilingual-Editor'!
TestCase subclass: #LocaleTest
	instanceVariableNames: ''
	classVariableNames: ''
	poolDictionaries: ''
	category: 'System-Localization'!
Smalltalk renameClassNamed: #NaturalLanguageTranslator2 as: #NaturalLanguageTranslator!
NaturalLanguageTranslator subclass: #InternalTranslator
	instanceVariableNames: 'generics '
	classVariableNames: 'AllKnownPhrases CachedTranslations '
	poolDictionaries: ''
	category: 'System-Localization'!
Object subclass: #TextDomainManager
	instanceVariableNames: ''
	classVariableNames: 'ClassCategories DefaultDomain'
	poolDictionaries: ''
	category: 'System-Localization'!

!GetTextTranslatorTest methodsFor: 'testing' stamp: 'tak 10/19/2007 14:53'!
testTranslateAll
	| translator legacy trn1 trn2|
	GetTextTranslator availableLanguageLocaleIDs 
		do: [:localeID |
			Transcript show: 'switching to ', (localeID isoString); cr.
			translator _ GetTextTranslator newForLocaleID: localeID.
			legacy _ InternalTranslator localeID: localeID.
			
			legacy translations keys
				do: [:each |
					trn1 _ translator translate: each.
					trn2 _ legacy translate: each.
					trn1 = each ifFalse: [  "skip phrases not translated yet"
						"ignore enclosing blanks for now"
						trn1 _ trn1 withBlanksTrimmed.
						trn2 _ trn2 withBlanksTrimmed.
						self assert: (trn1 = trn2).
					].
				].
		].! !


!GettextTest methodsFor: 'testing' stamp: 'tak 10/19/2007 22:00'!
testHeader
	"self debug: #testHeader"
	self assert: '' translated = ''! !


!LanguageEditor methodsFor: 'gui methods' stamp: 'tak 10/19/2007 13:37'!
searchTranslation: aString 
	| results index |
	results := self translations
				select: [:each | ""
					('*' , aString , '*' match: each)
						or: ['*' , aString , '*' match: (self translator translate: each)]].
	""
	results isEmpty
		ifTrue: [""
			self inform: 'no matches for' translated , ' ''' , aString , ''''.
			^ self].
	""
	results size = 1
		ifTrue: [""
			self selectTranslationPhrase: results first.
			^ self].
	""
	index := (PopUpMenu
				labelArray: (results
						collect: [:each | ""
							(each copy replaceAll: Character cr with: $\)
								, ' -> '
								, ((self translator translate: each) copy replaceAll: Character cr with: $\)]))
				startUpWithCaption: 'select the translation...' translated.
	""
	index isZero
		ifTrue: [""
			self beep.
			^ self].
	""
	self
		selectTranslationPhrase: (results at: index)! !

!LanguageEditor methodsFor: 'accessing' stamp: 'tak 10/19/2007 13:37'!
translation
	"answer the translation for the selected phrase"
	self selectedTranslation isZero
		ifTrue: [^ '<select a phrase from the upper list>' translated].
	""
	^ self translator
		translate: (self translations at: self selectedTranslation)! !

!LanguageEditor methodsFor: 'accessing' stamp: 'tak 10/19/2007 13:37'!
translations
	"answet the translator's translations"
	| allTranslations filterString |
	translations ifNotNil: [^translations].
	allTranslations := self translator translations keys.
	""
	filterString := self translationsFilter.
	""
	filterString isEmpty
		ifFalse: [allTranslations := allTranslations
						select: [:each | ""
							('*' , filterString , '*' match: each)
								or: ['*' , filterString , '*'
										match: (self translator translate: each)]]].
""
	^ translations _ allTranslations asSortedCollection asArray! !

!LanguageEditor methodsFor: 'accessing' stamp: 'tak 10/19/2007 13:37'!
untranslated
	"answer the translator's untranslated phrases"
	

	| all filterString |
	untranslated ifNotNil: [^ untranslated].
	all := self translator untranslated.
	""
	filterString := self untranslatedFilter.
	""
	filterString isEmpty
		ifFalse: [all := all
						select: [:each | ""
							('*' , filterString , '*' match: each)
								or: ['*' , filterString , '*'
										match: (self translator translate: each)]]].
	""
	^ untranslated _ all asSortedCollection asArray! !

!LanguageEditor methodsFor: 'reporting' stamp: 'tak 10/19/2007 13:37'!
printTranslationsReportOn: aStream 
	"append to aStream a report of the receiver's translations"
	| originalPhrases |
	aStream nextPutAll: '!!';
		 nextPutAll: 'translations' translated;
		 cr.

	originalPhrases := self translator translations keys asSortedCollection.

	originalPhrases
		do: [:each | 
			aStream
				nextPutAll: ('|{1}|{2}|' format: {self asHtml: each. self
							asHtml: (self translator translate: each)});
				 cr].

	aStream cr; cr! !


!LanguageEditor class methodsFor: 'instance creation' stamp: 'tak 10/19/2007 15:14'!
on: localeID 
	"answer an instance of the receiver on aLanguage"
	^ self new
		initializeOn: (InternalTranslator cachedTranslations
				at: localeID
				ifAbsent: [self
						error: ('Translator for {1} is not found' translated format: {localeID})])! !


!Locale class methodsFor: 'accessing' stamp: 'yo 7/16/2007 15:02'!
switchTo: locale gently: gentlyFlag
	"Locale switchTo: (Locale isoLanguage: 'de')"
	| availableID |
	availableID := (NaturalLanguageTranslator availableForLocaleID: locale localeID) localeID.
	Current localeID = availableID
		ifFalse: [Previous _ Current.
				CurrentPlatform := Current := Locale localeID: availableID.
				gentlyFlag ifTrue: [self localeChangedGently] ifFalse: [self localeChanged]]! !


!LocaleID class methodsFor: 'instance creation' stamp: 'tak 10/19/2007 17:06'!
posixName: aString 
	^ self
		isoString: (aString copyReplaceAll: '_' with: '-')! !


!LocaleTest methodsFor: 'testing' stamp: 'tak 10/19/2007 17:01'!
testIsFontAvailable
	"self debug: #testIsFontAvailable"
	"It take a log time so it is comment out now."
	true ifTrue: [^self].
	(Locale isoLanguage: 'ja') languageEnvironment removeFonts.
	self assert: (Locale isoLanguage: 'en') languageEnvironment isFontAvailable.
	"Next test should fail after installing Japanese font"
	self assert: (Locale isoLanguage: 'ja') languageEnvironment isFontAvailable not.
	(Locale isoLanguage: 'ja') languageEnvironment installFont.
	self assert: (Locale isoLanguage: 'ja') languageEnvironment isFontAvailable! !

!LocaleTest methodsFor: 'testing' stamp: 'tak 10/19/2007 17:06'!
testLocaleID
	"self debug: #testLocaleID"
	self assert: (LocaleID isoString: 'es') posixName = 'es'.
	self assert: (LocaleID isoString: 'es-MX') posixName = 'es_MX'.
	self assert: (LocaleID posixName: 'es_MX') posixName = 'es_MX'.
	self assert: (LocaleID posixName: 'es') posixName = 'es'.
	self assert: (LocaleID posixName: 'es_MX') isoString = 'es-MX'.
! !


!MOFile methodsFor: 'public' stamp: 'tak 10/19/2007 21:59'!
translationFor: aString 
	| trans |
	aString isEmpty
		ifTrue: [^ '']. "Gettext header"
	trans := self searchByDictionary: aString.
	trans isNil
		ifTrue: [^ aString]
		ifFalse: [^ trans]! !


!NaturalLanguageTranslator methodsFor: 'printing' stamp: 'tak 10/19/2007 13:59'!
printOn: aStream
	aStream nextPutAll: self class name; nextPut: $(; print: self localeID; nextPut: $)! !

!NaturalLanguageTranslator methodsFor: 'translation' stamp: 'tak 10/19/2007 13:38'!
translate: aString inDomain: aDomainName
	^ aString! !


!GetTextTranslator methodsFor: 'translation' stamp: 'tak 10/19/2007 13:38'!
translate: aString inDomain: aDomainName
	| mo |
	mo _ self moFileForDomain: aDomainName.
	^mo isNil 
		ifTrue: [aString] 
		ifFalse: [mo translationFor: aString]
! !


!InternalTranslator methodsFor: 'translation' stamp: 'tak 10/19/2007 15:11'!
translate: aString inDomain: aDomainName 
	| translator |
	^ self generics
		at: aString
		ifAbsent: [self localeID hasParent
				ifTrue: [translator := self class cachedTranslations
								at: self localeID parent
								ifAbsent: [^ aString].
					translator translate: aString inDomain: aDomainName]
				ifFalse: [aString]]! !


!NaturalLanguageTranslator class methodsFor: 'accessing' stamp: 'tak 10/19/2007 13:47'!
availableLanguageLocaleIDs
	"Return the locale ids for the currently available languages.  
	Meaning those which either internally or externally have  
	translations available."
	"NaturalLanguageTranslator availableLanguageLocaleIDs"
	^ self translators values collect:[:each | each localeID]! !

!NaturalLanguageTranslator class methodsFor: 'class initialization' stamp: 'tak 10/19/2007 15:25'!
initialize
	Smalltalk addToStartUpList: NaturalLanguageTranslator after: FileDirectory.
! !

!NaturalLanguageTranslator class methodsFor: 'class initialization' stamp: 'tak 10/19/2007 15:29'!
privateStartUp
	self resetCaches.
	GetTextTranslator privateStartUp.
	InternalTranslator privateStartUp.
	self localeChanged: LocaleID current.! !

!NaturalLanguageTranslator class methodsFor: 'class initialization' stamp: 'tak 10/19/2007 15:29'!
startUp: resuming 
	resuming
		ifFalse: [^ self].
	self privateStartUp.! !


!GetTextTranslator class methodsFor: 'accessing' stamp: 'tak 10/19/2007 17:10'!
availableLanguageLocaleIDs
	"GetTextTranslator availableLanguageLocaleIDs"
	| ids dirs localeDirForLang|
	ids _ Set new.
	dirs _ Set new.
	dirs addAll: LocaleDirsForDomain values.
	dirs addAll: self defaultLocaleDirs.
	dirs do: [:dir |
		| localesDir |
		localesDir _ FileDirectory on: dir. 
		localesDir directoryNames
				do: [:langDirName | 
					| localeID  |
					localeID _ LocaleID posixName: langDirName.
					localeDirForLang _ localesDir directoryNamed: (self langDirNameForLocaleID: localeID).
					localeDirForLang ifNotNil: [
						(localeDirForLang fileNamesMatching: '*.mo') ifNotEmpty: [ids add: localeID]
					]
				].
	].
	^ids! !

!GetTextTranslator class methodsFor: 'class initialization' stamp: 'tak 10/19/2007 15:30'!
privateStartUp
	self availableLanguageLocaleIDs do: [ :localeID |
		NaturalLanguageTranslator translators 
				at: localeID 
				put: (self newForLocaleID: localeID).
	]! !

!GetTextTranslator class methodsFor: 'translation data layout' stamp: 'tak 10/19/2007 21:35'!
systemDefaultLocaleDirs
	| dirs sepa localesDirName |
	sepa _ FileDirectory slash.
	dirs _ OrderedCollection new.
	localesDirName _ 'lang'.
	dirs add:  (SmalltalkImage current imagePath) , sepa , localesDirName.
	dirs add:  (SmalltalkImage current vmPath) , sepa , localesDirName.
	^dirs! !


!InternalTranslator class methodsFor: 'accessing' stamp: 'tak 10/19/2007 13:47'!
availableLanguageLocaleIDs
	"Return locale ids for the internal translation dictionary."
	"InternalTranslator availableLanguageLocaleIDs"
	^ CachedTranslations values collect:[:each | each localeID]! !

!InternalTranslator class methodsFor: 'accessing' stamp: 'tak 10/19/2007 13:28'!
mergeLegacyTranslators
	self availableLanguageLocaleIDs
		do: [:localeID | (NaturalLanguageTranslator translators includesKey: localeID)
				ifFalse: [NaturalLanguageTranslator translators
						at: localeID
						put: (self newLocaleID: localeID)]]! !

!InternalTranslator class methodsFor: 'class initialization' stamp: 'tak 10/19/2007 15:33'!
initialize
	"InternalTranslator initialize"

	FileList registerFileReader: self! !

!InternalTranslator class methodsFor: 'class initialization' stamp: 'tak 10/19/2007 15:28'!
privateStartUp
	self loadAvailableExternalLocales.
	self mergeLegacyTranslators.
! !

!InternalTranslator class methodsFor: 'class initialization' stamp: 'tak 10/19/2007 15:34'!
resetCaches
	CachedTranslations := nil.
! !


!Project methodsFor: 'language' stamp: 'yo 7/16/2007 21:07'!
chooseNaturalLanguage
	"Put up a menu allowing the user to choose the natural language for the project"

	| aMenu availableLanguages item |
	aMenu _ MenuMorph new defaultTarget: self.
	aMenu addTitle: 'choose language' translated.
	aMenu lastItem setBalloonText: 'This controls the human language in which tiles should be viewed.  It is potentially extensible to be a true localization mechanism, but initially it only works in the classic tile scripting system.  Each project has its own private language choice' translated.
	Preferences noviceMode
		ifFalse:[aMenu addStayUpItem].

	availableLanguages := NaturalLanguageTranslator availableLanguageLocaleIDs
										asSortedCollection:[:x :y | x displayName < y displayName].

	availableLanguages do:
		[:localeID |
			item _ aMenu addUpdating: #stringForLanguageNameIs: target: Locale selector:  #switchAndInstallFontToID:gently: argumentList: {localeID. true} extraIcon: (Locale localeID: localeID) iconForNativeLanguage.
			item wordingArgument: localeID.].
	aMenu popUpInWorld

"Project current chooseNaturalLanguage"! !


!String methodsFor: 'translating' stamp: 'tak 10/19/2007 13:28'!
translatedTo: localeID inDomain: aDomainName
	"answer the receiver translated to the given locale id in the textdomain"
	^ NaturalLanguageTranslator translate: self 
								toLocaleID: localeID 
								inDomain:  aDomainName! !

InternalTranslator class removeSelector: #availableForLocaleID:!
InternalTranslator class removeSelector: #cleanUpCache!
InternalTranslator class removeSelector: #current!
InternalTranslator class removeSelector: #default!
InternalTranslator class removeSelector: #extractPhrases!
InternalTranslator initialize!
InternalTranslator class removeSelector: #startUp!
InternalTranslator class removeSelector: #startUp:!
InternalTranslator class removeSelector: #translate:to:!
GetTextTranslator class removeSelector: #availableLocaleIDs!
GetTextTranslator class removeSelector: #loadAvailableTranslators!

!GetTextTranslator class reorganize!
('accessing' availableLanguageLocaleIDs)
('class initialization' initialize privateStartUp)
('instance creation' newForLocaleID:)
('translation data layout' defaultLocaleDirs localeDirForDomain: localeDirsForDomain: setLocaleDir:forDoamin: systemDefaultLocaleDirs userDefaultLocaleDirs)
('private' findMOForLocaleID:domain: langDirNameForLocaleID: localeDirsForDomain moNameForDomain:)
!

NaturalLanguageTranslator initialize!
NaturalLanguageTranslator class removeSelector: #translate:toLocaleID:!

!NaturalLanguageTranslator class reorganize!
('accessing' availableForLocaleID: availableLanguageLocaleIDs current default localeChanged: removeLocaleID: resetCaches translators)
('class initialization' initialize privateStartUp startUp:)
('translation' translate:toLocaleID:inDomain:)
!

InternalTranslator removeSelector: #displayLanguage!
InternalTranslator removeSelector: #displayName!
InternalTranslator removeSelector: #isoCountry!
InternalTranslator removeSelector: #isoLanguage!
InternalTranslator removeSelector: #localeID!
InternalTranslator removeSelector: #localeID:!
InternalTranslator removeSelector: #printOn:!
InternalTranslator removeSelector: #translate:!
InternalTranslator removeSelector: #translate:in:!
InternalTranslator removeSelector: #translationFor:!
InternalTranslator removeSelector: #writeAsMimeString!
NaturalLanguageTranslator subclass: #InternalTranslator
	instanceVariableNames: 'generics'
	classVariableNames: 'AllKnownPhrases CachedTranslations'
	poolDictionaries: ''
	category: 'System-Localization'!

!InternalTranslator reorganize!
('accessing' translations untranslated)
('fileIn/fileOut' fileOutHeader fileOutOn: fileOutOn:keys:withBOM: nextChunkPut:on: scanFrom:)
('translation' checkPhrase:translation: phrase:translation: rawPhrase:translation: rawRemoveUntranslated: removeTranslationFor: removeUntranslated: translate:inDomain:)
('user interface' defaultBackgroundColor fileOutHeaderOn: fileOutHeaderOn:withBOM:)
('private' generics)
('private store-retrieve' loadFromFileNamed: loadFromRefStream: loadFromStream: mergeTranslations: processExternalObject: saveToFileNamed:)
!

GetTextTranslator removeSelector: #translationFor:inDomain:!

!GetTextTranslator reorganize!
('accessing' loadMOFiles reloadMOFiles)
('initialize-release' initialize)
('language switching' setCurrent)
('translation' translate:inDomain:)
('private' loadMOFileForDomain: moFileForDomain:)
!

NaturalLanguageTranslator removeSelector: #displayLanguage!
NaturalLanguageTranslator removeSelector: #displayName!
NaturalLanguageTranslator removeSelector: #isoCountry!
NaturalLanguageTranslator removeSelector: #isoLanguage!
NaturalLanguageTranslator removeSelector: #translationFor:inDomain:!

!NaturalLanguageTranslator reorganize!
('accessing' localeID localeID:)
('language switching' setCurrent)
('printing' printOn:)
('translation' translate: translate:inDomain:)
!

"Postscript:
"
InternalTranslator cachedTranslations keysAndValuesDo: [:key :translator |
	translator localeID: key].
Smalltalk removeFromStartUpList: InternalTranslator.
NaturalLanguageTranslator initialize.
NaturalLanguageTranslator startUp: true.
!