'From etoys2.2 of 1 October 2007 [latest update: #1775] on 14 November 2007 at 11:35:39 am'!
"Change Set:		AddFileDialogToCatalog-yo
Date:			14 November 2007
Author:			Yoshiki Ohshima

Even on XO, there should be a way to access the files on the file system."!


!FileList2 class methodsFor: 'blue ui' stamp: 'yo 11/14/2007 11:22'!
morphicViewGeneralLoaderInWorld: aWorld 
	"
	FileList2 morphicViewGeneralLoaderInWorld: self currentWorld
	"
	(self
		morphicViewProjectLoader2InWorld: aWorld
		title: 'Find...' translated
		reallyLoad: true
		dirFilterType: #initialDirectoryList
		isGeneral: true) openInWorld: aWorld.
! !

!FileList2 class methodsFor: 'blue ui' stamp: 'yo 11/14/2007 11:22'!
morphicViewProjectLoader2InWorld: aWorld reallyLoad: aBoolean dirFilterType: aSymbol 
	"Put up a blue file-list for loading etoy projects."
"
FileList2 morphicViewProjectLoader2InWorld: self currentWorld reallyLoad: true dirFilterType: #limitedSuperSwikiDirectoryList
"
	(self
		morphicViewProjectLoader2InWorld: aWorld
		title: 'Load A Project' translated
		reallyLoad: aBoolean
		dirFilterType: aSymbol
		isGeneral: false) openInWorld: aWorld
! !

!FileList2 class methodsFor: 'blue ui' stamp: 'yo 11/14/2007 09:31'!
morphicViewProjectLoader2InWorld: aWorld title: title reallyLoad: aBoolean dirFilterType: aSymbol isGeneral: isGeneral
	"Put up a blue file-list for loading etoy projects."
"
FileList2 morphicViewProjectLoader2InWorld: self currentWorld reallyLoad: true dirFilterType: #limitedSuperSwikiDirectoryList
"

	| window aFileList actionRow |

	aFileList _ self buildFileListDirFilterType: aSymbol.
	window := self buildMorphicWindow: aFileList title: title. 

	actionRow _ self buildLoadButtons: window fileList: aFileList reallyLoad: aBoolean.

	isGeneral
		ifTrue: [self buildFileTypeButtons: window actionRow: actionRow fileList: aFileList].

	self buildPane: aWorld fileList: aFileList window: window dirFilterType: aSymbol.
	window addMorphBack: actionRow.

	window fullBounds.
	window position: aWorld topLeft + (aWorld extent - window extent // 2).
	window beSticky.
	aFileList sortByName.
	aFileList postOpen.
	^ window! !


!PartsBin class methodsFor: 'thumbnail cache' stamp: 'yo 11/14/2007 11:19'!
rebuildIconsWithProgress
	"Put up an eye-catching progress morph while doing a complete rebuild of all the parts icons in the system."

	| fixBlock |
	fixBlock _ Project current displayProgressWithJump: 'Building icons' translated.
	self clearThumbnailCache.
	self cacheAllThumbnails.
	fixBlock value.
	ActiveWorld ifNotNil: [ActiveWorld fullRepaintNeeded]! !


!SugarNavigatorBar class methodsFor: 'utilitity' stamp: 'yo 11/14/2007 11:17'!
findAnythingMorph

	^ FileList2 morphicViewProjectLoader2InWorld: ActiveWorld
		title: 'Find...' translated
		reallyLoad: true
		dirFilterType: #initialDirectoryList
		isGeneral: true.! !

!SugarNavigatorBar class methodsFor: 'utilitity' stamp: 'yo 11/14/2007 11:18'!
supplementaryPartsDescriptions
	^ {DescriptionForPartsBin
		formalName: 'File Dialog' translatedNoop
		categoryList: #('Scripting')
		documentation: 'The list of files and directories' translatedNoop
		globalReceiverSymbol: #SugarNavigatorBar
		nativitySelector: #findAnythingMorph
	}! !

SugarNavigatorBar class removeSelector: #findAnything!
"Postscript:
"
PartsBin rebuildIconsWithProgress.
!