'From etoys2.3 of 3 December 2007 [latest update: #1847] on 17 December 2007 at 8:49:16 am'!
"Change Set:		RecordingControlCodecNaming
Date:			17 December 2007
Author:			Karl Ramberg

This changeset adds end user wording for compression choices eg: 'Vorbis (for music)' etc."!


!RecordingControls methodsFor: 'menu commands' stamp: 'kfr 12/17/2007 08:44'!
chooseCodec
	"Put up a menu allowing the user to choose which codec to use."

	| menu aName aCodec |
	menu := MenuMorph new defaultTarget: self.
	aCodec := recorder codec.
	aName := aCodec
		ifNil:
			['None']
		ifNotNil:
			[aCodec class visibleCodecName].
	menu title: 'Compression method' translated, '
(','Currently: ', aName, ')'.
	OggDriver isAvailable
		ifTrue: [menu
				add: 'Speex (for speech)'
				target: self
				selector: #changeCodec:name:
				argumentList: {OggSpeexCodec. OggSpeexCodec visibleCodecName}.
			menu
				add: 'Vorbis (for music)'
				target: self
				selector: #changeCodec:name:
				argumentList: {OggVorbisCodec. OggVorbisCodec visibleCodecName}].
	menu
		add: 'GSM (simple compression)'
		target: self
		selector: #changeCodec:name:
		argumentList: {GSMCodec.GSMCodec visibleCodecName}.
	menu
		add: 'No compression'
		target: self
		selector: #changeCodec:name:
		argumentList: {nil. 'None'}.

	recorder codec
		ifNil:
			[menu items last color: Color red]
		ifNotNil:
			[menu items do:
				[:itm | (itm arguments first = recorder codec class) ifTrue:
					[itm color: Color red]]].

	menu popUpInWorld! !