'From etoys3.0 of 28 February 2008 [latest update: #2002] on 18 May 2008 at 2:28:46 am'!
"Change Set:		pointTypeArrows-sw
Date:			18 May 2008
Author:			Scott Wallace

Fix for TRAC 7024: Up/Down button shown for location in viewer.  As Korakurider points out, up-down arrows on point-type readouts were meaningless as well as non-functional, so they are now removed.  Arguably a suffix arrow *shoud* appear on point-type tiles, but evidently that never worked (i.e. a suffix arrow did appear on point-type tiles but it never did anything); until operating the suffix arrow on a point-type tile can be made to do something (i.e. something comparable to what happens with number-type tiles) it is now removed from the UI."!


!Point methodsFor: '*green' stamp: 'sw 5/18/2008 00:48'!
newTileMorphRepresentative
	"Answer a tile that can carry a value of the receiver's type"

	^ TileMorph new "addArrows;" setLiteral: self; addSuffixIfCan! !


!PointType methodsFor: 'defaults' stamp: 'sw 5/18/2008 00:43'!
wantsArrowsOnTiles
	"Answer whether this data type wants up/down arrows on tiles representing its values"

	^ false! !


!TileMorph methodsFor: 'arrows' stamp: 'sw 5/18/2008 00:47'!
couldAddSuffixArrow
	"Answer whether it is appropriate for the receiver to bear a suffix arrow."

	| phrase pad |
	type = #operator ifTrue:
		[((owner isKindOf: PhraseTileMorph) and: [owner submorphs last == self] and: [#("Point" Number) includes: owner resultType])
			ifTrue: [^ true]].
	(#(literal function parameter) includes: type) ifFalse: [^ false].
	(pad := self ownerThatIsA: TilePadMorph) ifNil: [^ false].

	(#("Point" Number) includes: pad type) ifFalse: [^ false].

	phrase := pad owner.
	(phrase isKindOf: TimesRow) ifTrue: [^ true].  "times-repeat situation"
	(phrase isKindOf: PhraseTileMorph)
		 ifTrue:
			[ ^ phrase submorphs last allMorphs includes: self]
		ifFalse:
			[^ phrase isKindOf: FunctionTile]! !