'From etoys3.0 of 7 March 2008 [latest update: #2068] on 1 August 2008 at 2:10:20 pm'!
"Change Set:		buddiesFlap-bf
Date:			1 August 2008
Author:			Bert Freudenberg

Use translated name to find buddies flap, do not translate holder morph name"!


!SugarLauncher methodsFor: 'presence' stamp: 'bf 8/1/2008 14:08'!
badgeFlap
	"This finds or creates a flap to hold badges"

	| translatedFlapName aFlapTab outer leftStrip rightStrip holder |
	translatedFlapName := 'Buddies' translated.
	aFlapTab := Flaps globalFlapTab: translatedFlapName.
	aFlapTab ifNotNil: [^aFlapTab].

	aFlapTab := FlapTab new.
	aFlapTab assureExtension visible: false.
	aFlapTab setProperty: #rigidThickness toValue: true.

	outer := AlignmentMorph newRow.
	outer assureExtension visible: false.
	outer clipSubmorphs: true.
	outer beTransparent.
	outer vResizing: #spaceFill; hResizing: #spaceFill.
	outer layoutInset: 0; cellInset: 0; borderWidth: 0.
	outer setProperty: #wantsHaloFromClick toValue: false.

	leftStrip := Morph new beTransparent.  "This provides space for tabs to be seen."
	leftStrip layoutInset: 0; cellInset: 0; borderWidth: 0.
	leftStrip width:  20.
	leftStrip hResizing: #rigid; vResizing: #spaceFill.
	outer addMorphBack: leftStrip.   

	rightStrip := AlignmentMorph newColumn.
	rightStrip color: (Color green veryMuchLighter alpha:  0.2).
	rightStrip layoutInset: 0; cellInset: 0; borderWidth: 0.
	rightStrip setProperty: #wantsHaloFromClick toValue: false.
	outer addMorphBack: rightStrip.
	outer clipSubmorphs: true.
	
	holder := Morph new.
	holder name: 'Badges'.
	holder position: 0@100.
	holder layoutPolicy: TableLayout new.
	holder color: Color red muchLighter;
		listDirection: #topToBottom;
		hResizing: #shrinkWrap;
		vResizing: #shrinkWrap;
		cellInset: 10;
		layoutInset: 10.

	rightStrip addMorphBack: holder.
	holder beSticky.

	aFlapTab referent ifNotNil: [aFlapTab referent delete].
	aFlapTab referent: outer.
	aFlapTab setName: translatedFlapName edge: #left color: Color red muchLighter.
	ActiveWorld addMorphFront: aFlapTab.
	aFlapTab adaptToWorld: ActiveWorld.
	aFlapTab computeEdgeFraction.

	aFlapTab position: (outer left @ outer top).
	outer extent: (200 @ ActiveWorld height).

	outer beFlap: true.
	outer beTransparent.

	aFlapTab referent hide.
	aFlapTab referentMargin: 0@75.

	outer beSticky.
	leftStrip beSticky.
	rightStrip beSticky.

	aFlapTab applyThickness: 200.
	aFlapTab fitOnScreen.
	aFlapTab referent show.
	aFlapTab show.
	aFlapTab makeFlapCompact: true.
	aFlapTab setToPopOutOnDragOver:  false.
	Flaps addGlobalFlap: aFlapTab.
	ActiveWorld addGlobalFlaps.
	ScriptingSystem cleanUpFlapTabsOnLeft.

	^aFlapTab! !

!SugarLauncher methodsFor: 'presence' stamp: 'bf 8/1/2008 14:08'!
badgeHolder
	"This finds or creates a flap to hold badges"

	^self badgeFlap referent submorphNamed: 'Badges'
! !