'From etoys3.0 of 7 March 2008 [Letztes Update: #2119] on 2 September 2008 at 5:33:45 pm'!
"Change Set:		noSaveDefault-bf
Date:			2 September 2008
Author:			Bert Freudenberg

Do not save default project automatically"!


!ReleaseBuilderSqueakland methodsFor: 'olpc' stamp: 'bf 9/2/2008 17:29'!
buildInitialScreenForOLPC
	"ReleaseBuilderSqueakland new buildInitialScreenForOLPC"

	"pre-load QuickGuideMorph class var IndexPage"
	QuickGuideMorph new preloadIndex.

	World
		submorphsDo: [:m | m delete].
	Flaps disableGlobalFlaps: false.
	Flaps enableEToyFlaps.

	ProjectLoading loadFromImagePath: 'Tutorials'.
	ProjectLoading loadFromImagePath: 'Gallery'.
	ProjectLoading loadFromImagePath: 'EtoysActivity'.

	(World submorphs select: [:e | e isMemberOf: ProjectViewMorph]) do: [:e | e delete].
	Project current
		setThumbnail: ((Project named: SugarLauncher welcomeProjectName)
			ifNotNilDo: [:p | p thumbnail]).! !


!SugarLauncher methodsFor: 'commands' stamp: 'bf 9/2/2008 17:33'!
quit
	self leaveSharedActivity.

	Project current name = self class welcomeProjectName
		ifTrue: [^Smalltalk quitPrimitive].

	Project current
		projectParameterAt: #sugarAutoSave put: true;
		storeOnServerWithNoInteractionThenQuit.! !

!SugarLauncher methodsFor: 'commands' stamp: 'bf 9/2/2008 17:28'!
welcome: aUrl
	"Sent either when running from Sugar, or at regular startUp otherwise"

	aUrl isEmpty ifFalse: [
		| url |
		url := (aUrl includes: $/)
			ifTrue: [aUrl]
			ifFalse: ['file:', (parameters at: 'BUNDLE_PATH'), '/', aUrl].
		^(url endsWith: '.pr')
			ifTrue: [Project fromUrl: url]
			ifFalse: [WorldState addDeferredUIMessage: [FileStream fileIn: (url copyAfter: $:)]]].

	"only enter launcher if no script given on cmd line"
	((SmalltalkImage current getSystemAttribute: 2) ifNil: [''])
		ifNotEmpty: [^self].

	Preferences eToyFriendly ifTrue: [
		(self includesParameter: 'SRC') ifFalse: [
			(Project named: self class welcomeProjectName) ifNotNilDo: [:p | p enter]]].! !


!SugarLauncher class methodsFor: 'accessing' stamp: 'bf 9/2/2008 17:27'!
welcomeProjectName
	^'Etoys Activity'! !

SugarLauncher removeSelector: #welcomeProjectName!