'From etoys4.0 of 5 November 2008 [latest update: #2237] on 6 August 2009 at 3:40:54 am'!
"Change Set:		saveProjectButton-sw
Date:			18 July 2009
Author:			Scott Wallace
Version 2 - 6 August 2009, incorporates Hilaire's recommendations.

Improves and harmonizes the help-messages and menu wordings involved with the side-by-side 'load project' and 'save project' buttons in the nav-bar.

Also changes 'Key Words' to 'Tags' in the project info dialog.

Also Changes 'Name' to 'Project Name' in the project info dialog."!


!EToyProjectDetailsMorph methodsFor: 'as yet unclassified' stamp: 'sw 8/6/2009 03:08'!
fieldToDetailsMappings

	^{
		{#description. 'projectdescription'. 'Description:' translatedNoop. 100}. 
		{#author .'projectauthor'. 'Author:' translatedNoop. 20}.
		{#category. 'projectcategory'. 'Category:' translatedNoop. 20}.
		{#subCategory. 'projectsubcategory'. 'Sub-category:' translatedNoop. 20}.
		{#keywords. 'projectkeywords'. 'Tags:' translatedNoop. 20}
	}
! !

!EToyProjectDetailsMorph methodsFor: 'as yet unclassified' stamp: 'sw 8/6/2009 03:06'!
rebuild

	| bottomButtons header |
	self removeAllMorphs.
	header := self addARow: {
		self lockedString: 'Please describe this project' translated.
	}.
	header color: ScriptingSystem baseColor.
	self addARow: {
		self lockedString: 'Project Name:' translated.
		self inAColumnForText: {self fieldForProjectName}
	}.
	self expandedFormat ifTrue: [
		self fieldToDetailsMappings do: [ :each |
			self addARow: {
				self lockedString: each third translated.
				self inAColumnForText: {(self genericTextFieldNamed: each first) height: each fourth}
			}.
		].
	].
	bottomButtons _ self expandedFormat ifTrue: [
		{
			self okButton.
			self cancelButton.
		}
	] ifFalse: [
		{
			self okButton.
			self expandButton.
			self cancelButton.
		}
	].
	self addARow: bottomButtons.
	self fillInDetails.! !


!EToyProjectQueryMorph methodsFor: 'as yet unclassified' stamp: 'sw 8/6/2009 03:06'!
rebuild

	self removeAllMorphs.
	self addARow: {
		self lockedString: 'Enter things to search for' translated.
	}.
	self addARow: {
		self lockedString: 'Project Name' translated.
		self inAColumnForText: {self fieldForProjectName}
	}.
	self fieldToDetailsMappings do: [ :each |
		self addARow: {
			self lockedString: each third translated.
			self inAColumnForText: {(self genericTextFieldNamed: each first) height: each fourth}
		}.
	].

	self addARow: {
		self okButton.
		self cancelButton.
	}.
	self fillInDetails.! !


!ProjectNavigationMorph methodsFor: 'the actions' stamp: 'sw 8/6/2009 03:21'!
doFindButtonMenuEvent: evt
	"Put up the find-projects dialog"

	| menu selection |

	menu _ CustomMenu new.
	menu 
		add: 'find a project' translated action: [self findAProjectSimple];
		add: 'find a project (more places)' translated action: [self findAProject];
		add: 'find any file' translated action: [self findAnything].
		"add: 'search the SuperSwiki' translated action: [self findSomethingOnSuperSwiki]."

	selection _ menu build startUpCenteredWithCaption: 'find (load) a project' translated.
	selection ifNotNil: [selection value]
! !

!ProjectNavigationMorph methodsFor: 'the actions' stamp: 'sw 8/6/2009 03:39'!
doPublishButtonMenuEvent: evt

	| menu selection |

	menu _ CustomMenu new.
	menu 
		add: 'publish' translated action: [self publishProject];
		add: 'publish as...' translated action: [self publishProjectAs];
		add: 'publish to different server' translated action: [self publishDifferent];
		addLine;
		add: 'edit project info' translated action: [self editProjectInfo].
	selection _ menu build startUpCenteredWithCaption: 'publish the current project' translated.
	selection ifNotNil: [selection value]! !

!ProjectNavigationMorph methodsFor: 'the buttons' stamp: 'sw 8/6/2009 03:40'!
buttonFind
	"Answer a button for finding/loading projects"

	^ self makeButton: 'FIND' translated balloonText: 'Find (load) another project. Hold mouse button down for further options.' translated for: #findAProjectSimple
! !

!ProjectNavigationMorph methodsFor: 'the buttons' stamp: 'sw 8/6/2009 03:40'!
buttonPublish
	"Answer a button for publishing the project "

	^ self makeButton: 'PUBLISH IT!!' translated balloonText: 'Publish (save) this project.
Hold mouse button down for further options' translated for: #publishProject! !


!SugarNavigatorBar methodsFor: 'buttons creation' stamp: 'sw 8/6/2009 02:49'!
buttonChoose
	"Answer a button for choosing objects from the Journal"

	^ self makeButton: 'FIND' translated balloonText: 'Find an entry in the Journal.  Hold mouse button down for further options.' translated for: #chooseObject
! !