'From etoys4.0 of 9 October 2008 [latest update: #2280] on 9 September 2009 at 3:01:55 pm'!
"Change Set:		BalloonsForLocalDir-yo
Date:			9 September 2009
Author:			Yoshiki Ohshima

Add balloon helps for local dirs to show the full path."!


!FileList2 methodsFor: 'initialization' stamp: 'yo 9/9/2009 14:58'!
initialDirectoryList

	| dir nameToShow dirList |
	dirList _ (FileDirectory on: '') directoryNames collect: [ :each |
		FileDirectoryWrapper with: (FileDirectory on: each) name: each model: self].
	dirList isEmpty ifTrue:[
		dirList _ Array with: (FileDirectoryWrapper 
			with: FileDirectory default 
			name: FileDirectory default localName 
			model: self)].
	dirList do: [:e | e balloonText: e withoutListWrapper pathName].
	dirList _ dirList,(
		ServerDirectory serverNames collect: [ :n | 
			dir _ ServerDirectory serverNamed: n.
			nameToShow _ n.
			(dir directoryWrapperClass with: dir name: nameToShow model: self)
				balloonText: dir realUrl
		]
	).
	^dirList! !

!FileList2 methodsFor: 'initialization' stamp: 'yo 9/9/2009 14:58'!
initialDirectoryListForProjects

	| dir nameToShow dirList |
	dirList _ (FileDirectory on: '') directoryNames collect: [ :each |
		FileDirectoryWrapper with: (FileDirectory on: each) name: each model: self].

	dirList isEmpty ifTrue:[
		dirList _ Array with: (FileDirectoryWrapper 
			with: FileDirectory default 
			name: FileDirectory default localName 
			model: self)].
	dirList do: [:e | e balloonText: e withoutListWrapper pathName].
	dirList _ dirList,((
		ServerDirectory serverNames select: [ :n | 
			(ServerDirectory serverNamed: n) isProjectSwiki.
		]) collect: [:n |
			dir _ ServerDirectory serverNamed: n.
			nameToShow _ n.
			(dir directoryWrapperClass with: dir name: nameToShow model: self)
				balloonText: dir realUrl
		]
	).
	^dirList! !

!FileList2 methodsFor: 'initialization' stamp: 'yo 9/9/2009 14:58'!
limitedSuperSwikiDirectoryList

	| dir nameToShow dirList localDirName localDir localList |

	dirList _ OrderedCollection new.
	localList _ OrderedCollection new.
	ServerDirectory serverNames do: [ :n | 
		dir _ ServerDirectory serverNamed: n.
		dir isProjectSwiki ifTrue: [
			nameToShow _ n.
			dirList add: ((dir directoryWrapperClass with: dir name: nameToShow model: self)
				balloonText: dir realUrl)
		].
	].
	ServerDirectory localProjectDirectories do: [ :each |
		localList add: (dirList add: (FileDirectoryWrapper with: each name: each localName model: self))
	].
	"Make sure the following are always shown, but not twice"
	localDirName := SecurityManager default untrustedUserDirectory.
	localDir := FileDirectory on: localDirName.
	((ServerDirectory localProjectDirectories collect: [:each | each pathName]) includes: localDirName)
			ifFalse: [localList add: (dirList add: (FileDirectoryWrapper with: localDir name: localDir localName model: self))].
	FileDirectory default pathName = localDirName
			ifFalse: [localList add: (dirList add: (FileDirectoryWrapper with: FileDirectory default name: FileDirectory default localName model: self))].
	(dirList anySatisfy: [:each | each withoutListWrapper acceptsUploads])
		ifFalse: [localList add: (dirList add: (FileDirectoryWrapper with: FileDirectory default name: FileDirectory default localName model: self))].
	localList do: [:e | e balloonText: e withoutListWrapper pathName].
	^dirList! !

!FileList2 methodsFor: 'initialization' stamp: 'yo 9/9/2009 15:00'!
limitedSuperSwikiPublishDirectoryList

	| dirList localDirName localDir localList |

	dirList _ self publishingServers.
	localList _ OrderedCollection new.
	ServerDirectory localProjectDirectories do: [ :each |
		localList add: (dirList add: (FileDirectoryWrapper with: each name: each localName model: self))].

	"Make sure the following are always shown, but not twice"
	localDirName := SecurityManager default untrustedUserDirectory.
	localDir := FileDirectory on: localDirName.
	((ServerDirectory localProjectDirectories collect: [:each | each pathName]) includes: localDirName)
			ifFalse: [localList add: (dirList add: (FileDirectoryWrapper with: localDir name: localDir localName model: self))].
	FileDirectory default pathName = localDirName
			ifFalse: [localList add: (dirList add: (FileDirectoryWrapper with: FileDirectory default name: FileDirectory default localName model: self))].
	localList do: [:e | e balloonText: e withoutListWrapper pathName].
	^dirList! !